home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er Special 16
/
64er_Magazin_Sonderheft_16_19xx_Markt__Technik_de_Side_A.d64
/
ls 9
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
76 lines
100 rem programmstart bewegen,animation
110 rem und kollision
120 rem
130 rem vorbereitungen
140 rem
150 rem farben
160 poke53280,5:poke53281,0
170 poke 53285,8:poke53286,11:poke53287,7
180 rem
190 xreg=53248:xlauf=53264
200 yreg=53249:koll=53279
210 bl=128:ba=128:be=135
220 rem
230 pokekoll,0:rem kollision loeschen
240 poke53276,1:rem sprite 0 multicolor
250 poke2040,bl:rem spritezeiger auf ersten block
260 pokexreg,0:pokexlauf,0:pokeyreg,117:rem anfangspos.
270 poke 53269,1:rem sprite 0 an
280 gosub490
290 rem
300 rem sprite animieren
310 rem
320 gosub670:rem joystickabfrage
330 if xp<=255 then poke xlauf,0
340 if xp>255 then poke xlauf,1:xp=xp-255
350 poke xreg,xp
360 gosub420:rem animation
370 gosub580:rem kollision
380 goto320
390 rem
400 rem naechster block
410 rem
420 bl=bl+1
430 ifbl>bethenbl=ba
440 poke2040,bl:rem bildwechsel
450 return
460 rem
470 rem boden zeichnen
480 rem
490 print"[147]";
500 forw=1to40:print" ";:nextw
510 print"[146]"
520 print"";
530 forw=1to5:printtab(28)" [146]":nextw
540 return
550 rem
560 rem kollisionsabfrage
570 rem
580 ifpeek(koll)=0thenreturn
590 ifpeek(53277)=0thenxp=xp-40:pokexreg,xp:poke53277,1:goto610
600 poke53277,0
610 pokekoll,0:rem kollisionsregister
620 rem loeschen
630 return
640 rem
650 rem joystickabfrage
660 rem
670 joy=peek(56321)
680 ifjoy=251then740
690 ifjoy=247then810
700 goto670
710 rem
720 rem joystick links
730 rem
740 xp=xp-3:ifxp<0thenxp=0
750 ifbl>135thenreturn
760 ba=136:be=143:bl=bl+8
770 return
780 rem
790 rem joystick rechts
800 rem
810 xp=xp+3
820 ifbl<136thenreturn
830 ba=128:be=135:bl=bl-8
840 return